parser.cup

/*================================================================*/ 
/* 
  JavaCup Specification for the JavaCup Specification Language
  by Scott Hudson, GVU Center, Georgia Tech, August 1995
  and Frank Flannery, Department of Computer Science, Princeton Univ,
  July 1996
  Bug Fixes: C. Scott Ananian, Dept of Electrical Engineering, Princeton
  University, October 1996. [later Massachusetts Institute of Technology]


  This JavaCup specification is used to implement JavaCup itself.
  It specifies the parser for the JavaCup specification language.
  (It also serves as a reasonable example of what a typical JavaCup
  spec looks like).

  The specification has the following parts:
    Package and import declarations
      These serve the same purpose as in a normal Java source file
      (and will appear in the generated code for the parser). In this 
      case we are part of the java_cup package and we import both the
      java_cup runtime system and Hashtable from the standard Java
      utilities package.

    Action code
      This section provides code that is included with the class encapsulating
      the various pieces of user code embedded in the grammar (i.e., the
      semantic actions).  This provides a series of helper routines and
      data structures that the semantic actions use.

    Parser code    
      This section provides code included in the parser class itself.  In
      this case we override the default error reporting routines.

    Init with and scan with 
      These sections provide small bits of code that initialize, then 
      indicate how to invoke the scanner.

    Symbols and grammar
      These sections declare all the terminal and non terminal symbols 
      and the types of objects that they will be represented by at runtime,
      then indicate the start symbol of the grammar (), and finally provide
      the grammar itself (with embedded actions).

    Operation of the parser
      The parser acts primarily by accumulating data structures representing
      various parts of the specification.  Various small parts (e.g., single
      code strings) are stored as static variables of the emit class and
      in a few cases as variables declared in the action code section.  
      Terminals, non terminals, and productions, are maintained as collection
      accessible via static methods of those classes.  In addition, two 
      symbol tables are kept:  
	symbols   maintains the name to object mapping for all symbols
	non_terms maintains a separate mapping containing only the non terms

      Several intermediate working structures are also declared in the action
      code section.  These include: rhs_parts, rhs_pos, and lhs_nt which
      build up parts of the current production while it is being parsed.
	
  Author(s)
    Scott Hudson, GVU Center, Georgia Tech.
    Frank Flannery, Department of Computer Science, Princeton Univ.
    C. Scott Ananian, Department of Electrical Engineering, Princeton Univ.

  Revisions
    v0.9a   First released version                     [SEH] 8/29/95
    v0.9b   Updated for beta language (throws clauses) [SEH] 11/25/95
    v0.10a  Made many improvements/changes. now offers:
              return value
              left/right positions and propagations
              cleaner label references
              precedence and associativity for terminals
              contextual precedence for productions
              [FF] 7/3/96
    v0.10b  Fixed %prec directive so it works like it's supposed to.
              [CSA] 10/10/96
    v0.10g   Added support for array types on symbols.
              [CSA] 03/23/98
    v0.10i  Broaden set of IDs allowed in multipart_id and label_id so
            that only java reserved words (and not CUP reserved words like
            'parser' and 'start') are prohibited.  Allow reordering of
	    action code, parser code, init code, and scan with sections,
	    and made closing semicolon optional for these sections.
	    Added 'nonterminal' as a terminal symbol, finally fixing a
	    spelling mistake that's been around since the beginning.
	    For backwards compatibility, you can still misspell the
	    word if you like.
*/
/*================================================================*/ 

package de.in.tum.www2.cup.internal;
import java_cup.runtime.*;
import java_cup.runtime.ComplexSymbolFactory.ComplexSymbol;
import java.util.Hashtable;
import java.util.Stack;
import java.util.List;
import java.util.ArrayList;
import de.in.tum.www2.cup.*;
import de.in.tum.www2.cup.ast.*;


/*----------------------------------------------------------------*/ 

action code {:
  /** helper routine to clone a new production part adding a given label */
  protected production_part add_lab(production_part part, String lab)
    throws internal_error
    {
      /* if there is no label, or this is an action, just return the original */
      if (lab == null || part.is_action()) return part;

      /* otherwise build a new one with the given label attached */
      return new symbol_part(((symbol_part)part).the_symbol(),lab);
    }

  /** max size of right hand side we will support */
  protected final int MAX_RHS = 200;

  /** array for accumulating right hand side parts */
  protected production_part[] rhs_parts = new production_part[MAX_RHS];

  /** where we are currently in building a right hand side */
  protected int rhs_pos = 0;

  /** start a new right hand side */
  protected void new_rhs() {rhs_pos = 0; }

  /** add a new right hand side part */
  protected void add_rhs_part(production_part part) throws java.lang.Exception
    {
      if (rhs_pos >= MAX_RHS)
	throw new Exception("Internal Error: Productions limited to " + 
			     MAX_RHS + " symbols and actions"); 

      rhs_parts[rhs_pos] = part;
      rhs_pos++;
    }

  /** string to build up multiple part names */
  protected String multipart_name = new String();
  protected Stack multipart_names = new Stack();

  /** table of declared symbols -- contains production parts indexed by name */
  protected Hashtable symbols = new Hashtable();

  /** table of just non terminals -- contains non_terminals indexed by name */
  protected Hashtable non_terms = new Hashtable();

  /** declared start non_terminal */
  protected non_terminal start_nt = null;

  /** left hand side non terminal of the current production */
  protected non_terminal lhs_nt;

  /** Current precedence number */
  int _cur_prec = 0;

  /** Current precedence side */
  int _cur_side = assoc.no_prec;

  /** update the precedences we are declaring */
  protected void update_precedence(int p) {
    _cur_side = p;
    _cur_prec++;
  }
  /** add relevant data to terminals */ 
  protected void add_precedence(String term) {
    if (term == null) {
      System.err.println("Unable to add precedence to nonexistent terminal");
    } else {
      symbol_part sp = (symbol_part)symbols.get(term);
      if (sp == null) {
	System.err.println("Could find terminal " + term + " while declaring precedence");
      } else {
	symbol sym = sp.the_symbol();
	if (sym instanceof terminal) 
	  ((terminal)sym).set_precedence(_cur_side, _cur_prec);
	else System.err.println("Precedence declaration: Can't find terminal " + term);
      }
    }
  }




  Stack<ComplexSymbol> head_tokens = new Stack<ComplexSymbol> ();
  List<IProductionRightPart> rhs_accumulator = new ArrayList<IProductionRightPart>();
  
  protected void ast_add_rhs_part(IProductionRightPart part)
  {
	rhs_accumulator.add(part);
  }

  protected ArrayList<IProductionRightPart> ast_get_rhs_parts_copy ()
  {
  	return new ArrayList<IProductionRightPart>(rhs_accumulator);
  }
  
  protected void ast_new_rhs()
  {
  	rhs_accumulator.clear();
  }

  protected void ast_add_precedence(ComplexSymbol head, Object lst)
  {
	Precedence p = new Precedence(_cur_side, (List<Terminal>) lst, 
	  							new Range(Position.fromComplexSymbolLeft(head),
	  								Position.fromComplexSymbolRight((ComplexSymbol) stack.peek()
	  							)
	  							));
	parserResult.precedences.add(p);
  }
  
:};

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

parser code {:

  private java.io.InputStream input_stream;
  private ErrorManager errMan;
  private CupContext context;
  private terminal.terminal_shared terminal_shared;
  private non_terminal.non_terminal_shared non_terminal_shared;
  private ParserResult parserResult;

  public void init(ErrorManager errMan, CupContext context, java.io.InputStream is) {
  	this.errMan = errMan;
  	this.context = context;
  	this.terminal_shared = terminal.getShared(context);
  	this.non_terminal_shared = non_terminal.getShared(context);
  	this.input_stream = is;
  }
  
  public ParserResult getResult() {
  	return parserResult;
  }
  
 /* override error routines */
  protected Lexer lexer;
  public void report_fatal_error(
    String   message,
    Object   info)
    {
      done_parsing();
      if (info instanceof Symbol)
      	errMan.Fatal(ErrorSource.Parser, message + "\nCan't recover from previous error(s), giving up.",(ComplexSymbol)info);
      else
      	errMan.Fatal(ErrorSource.Parser, message + "\nCan't recover from previous error(s), giving up.",(ComplexSymbol)cur_token);
      throw new ParserAbortException();
    }

    public void report_error(String message, Object info)
    {
      if (info instanceof Symbol)
         errMan.Error(ErrorSource.Parser, message, (ComplexSymbol) info);
      else
         errMan.Error(ErrorSource.Parser, message, (ComplexSymbol) cur_token);
    }
:};

/*---------------------------------------------------------------- */

init with {:
    ComplexSymbolFactory f = new ComplexSymbolFactory();
    symbolFactory = f;
    parserResult = new ParserResult();
    lexer = new Lexer(errMan, f, this.input_stream);
:}
/*lexer.init(); :};*/
scan with {: 
    return lexer.next_token(); 
:};

/*----------------------------------------------------------------*/ 

terminal
  PACKAGE, IMPORT, CODE, ACTION, PARSER, TERMINAL, NON, INIT, SCAN, WITH, 
  START, SEMI, COMMA, STAR, DOT, COLON, COLON_COLON_EQUALS, BAR, PRECEDENCE,
  LEFT, RIGHT, NONASSOC, PERCENT_PREC, LBRACK, RBRACK, NONTERMINAL, GT, LT,
  QUESTION, SUPER, EXTENDS, CLASS;

terminal String ID, CODE_STRING;

non terminal
  spec, package_spec, import_list, action_code_part, 
  code_parts, code_part, opt_semi, non_terminal,
  parser_code_part, symbol_list, start_spec, production_list, 
  multipart_id, import_spec, import_id, init_code, scan_code, symbol, 
  type_id, term_name_list, non_term_name_list, production, prod_part_list, 
  prod_part, new_term_id, new_non_term_id, rhs_list, rhs, empty,
  precedence_list, preced, preced_type, terminal_list, precedence_l, declares_term, 
  declares_non_term, class_name;

non terminal String  nt_id, symbol_id, label_id, opt_label, terminal_id,
                     term_id, robust_id, typearglist, typearguement, wildcard;

/*----------------------------------------------------------------*/ 

start with spec;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

spec ::= 
	{:
          /* declare "error" as a terminal */
          symbols.put("error", new symbol_part(terminal_shared.getError()));

          /* declare start non terminal */
          non_terms.put("$START", non_terminal_shared.getSTART_nt());
	:}
	package_spec
	import_list
	class_name
	code_parts
	symbol_list
	precedence_list
	start_spec
	production_list
	|
	/* error recovery assuming something went wrong before symbols 
	   and we have TERMINAL or NON TERMINAL to sync on.  if we get
	   an error after that, we recover inside symbol_list or 
	   production_list 
	*/
	error 
	symbol_list
	precedence_list
	start_spec
	production_list
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

package_spec ::= 
	PACKAGE : p
	multipart_id
	{:
	  /* save the package name */
	  context.package_name = multipart_name;

	  parserResult.pack = new de.in.tum.www2.cup.ast.Package(
	  					new Name (multipart_name, null), // TODO: from, to 
	  					new Range(Position.fromLocation(pxleft),
	  					Position.fromComplexSymbolRight((ComplexSymbol) cur_token)));

	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	:}
	SEMI
	|
	empty
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

import_list ::=
	import_list
	import_spec
	|
	empty
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

import_spec ::=
	IMPORT {:
		head_tokens.push((ComplexSymbol) stack.peek());
	:}
	import_id
	{:
	  /* save this import on the imports list */
	  context.import_list.push(multipart_name);

      Import imprt = new Import(
      					new Name (multipart_name, null), // TODO: from, to 
	  					new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
      					Position.fromComplexSymbolRight((ComplexSymbol) cur_token)));
      parserResult.imports.add(imprt);
      
	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	:}
	SEMI
	;

class_name ::=
    empty |
    CLASS {:
    	head_tokens.push((ComplexSymbol) stack.peek());
    :} ID:id SEMI
    {:
     context.parser_class_name = id;
     context.symbol_const_class_name = id + "Sym";
     
     parserResult.className = new ClassName (
     							new Name(id, null), //jrTODO: positions
								new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
								Position.fromComplexSymbolRight((ComplexSymbol) stack.peek())));
     
    :}
    ;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

// allow any order; all parts are optional. [CSA, 23-Jul-1999]
// (we check in the part action to make sure we don't have 2 of any part)
code_part ::=
	action_code_part | parser_code_part | init_code | scan_code ;
code_parts ::= 
	| code_parts code_part;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

action_code_part ::= 
	ACTION {:
		head_tokens.push((ComplexSymbol) stack.peek());
	:} CODE CODE_STRING : user_code opt_semi
	{:
	  if (context.action_code!=null)
	    errMan.Warning(ErrorSource.Parser,
	    		"Redundant action code (skipping)",
	    		Position.fromLocation(user_codexleft));
	  else { /* save the user included code string */
	    context.action_code = user_code;
	    parserResult.actionCode = new SpecialCodeBlock(
	    							SpecialCodeBlock.BlockType.Action,
	    							user_code, 
	    							new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
	    							Position.fromComplexSymbolRight((ComplexSymbol) cur_token))); // jrTODO!
	  }
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

parser_code_part ::= 
	PARSER {:
		head_tokens.push((ComplexSymbol) stack.peek());
	:} CODE CODE_STRING:user_code opt_semi
	{:
	  if (context.parser_code!=null)
	    errMan.Warning(ErrorSource.Parser,
	    				"Redundant parser code (skipping)",
	    		Position.fromLocation(user_codexleft));
	  else { /* save the user included code string */
	    context.parser_code = user_code;
	    parserResult.parserCode = new SpecialCodeBlock(
	    							SpecialCodeBlock.BlockType.Parser,
	    							user_code,
	    							new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
	    							Position.fromComplexSymbolRight((ComplexSymbol) cur_token))); // jrTODO!
		}
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

init_code ::= 
	INIT {:
		head_tokens.push((ComplexSymbol) stack.peek());
	:} WITH CODE_STRING:user_code opt_semi
	{: 
	  if (context.init_code!=null)
	    errMan.Warning(ErrorSource.Parser, "Redundant init code (skipping)", 
	    		Position.fromLocation(user_codexleft));
	  else {/* save the user code */
	    context.init_code = user_code;
	    parserResult.initCode = new SpecialCodeBlock(
	    							SpecialCodeBlock.BlockType.Init,
	    							user_code, 
	    							new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
	    							Position.fromComplexSymbolRight((ComplexSymbol) cur_token))); // jrTODO!
		}
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

scan_code ::=
	SCAN {:
		head_tokens.push((ComplexSymbol) stack.peek());
	:} WITH CODE_STRING:user_code opt_semi
	{: 
	  if (context.scan_code!=null)
	    errMan.Warning(ErrorSource.Parser, "Redundant scan code (skipping)", 
	    		Position.fromLocation(user_codexleft));
	  else {
	  	 /* save the user code */
	    context.scan_code = user_code;
	    parserResult.scanCode = new SpecialCodeBlock(
	    							SpecialCodeBlock.BlockType.Scan,
	    							user_code, 
	    							new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
	    							Position.fromComplexSymbolRight((ComplexSymbol) cur_token))); // jrTODO!
	    
	  }
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

symbol_list ::= symbol_list symbol | symbol;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

symbol ::= 
	TERMINAL
	type_id : tid
	declares_term : lst {:
	
		//jrTODO: BUG? this is strange!!! -> there must be a better way 
		//        to refer to these terminals.
		ComplexSymbol terminal = (ComplexSymbol) stack.elementAt(stack.size()-2);		

		parserResult.symbols.add(new TypedTerminalDeclaration(
							(String) tid,
							(List<Terminal>) lst,
							new Range(Position.fromComplexSymbolLeft(terminal),
							Position.fromComplexSymbolRight((ComplexSymbol) stack.peek()))));
	:}
	|
	TERMINAL
	declares_term : lst {:
		//jrTODO: BUG? this is strange!!! -> there must be a better way 
		//        to refer to these terminals.
		ComplexSymbol terminal = (ComplexSymbol) stack.elementAt(stack.size()-2);		

		parserResult.symbols.add(new TerminalDeclaration(
							(List<Terminal>) lst,
							new Range(Position.fromComplexSymbolLeft(terminal),
							Position.fromComplexSymbolRight((ComplexSymbol) stack.peek()))));
		;
	:}
	|
	non_terminal
	type_id : tid
	declares_non_term : lst {:
	
		//jrTODO: BUG? this is strange!!! -> there must be a better way 
		//        to refer to these terminals.
		ComplexSymbol nonTerminal = (ComplexSymbol) stack.elementAt(stack.size()-3);		
		parserResult.symbols.add(new TypedNonTerminalDeclaration(
							(String) tid,
							(List<NonTerminal>) lst,
							new Range(Position.fromComplexSymbolLeft(nonTerminal),
							Position.fromComplexSymbolRight((ComplexSymbol) stack.peek()))));
	:}
	|
	non_terminal
	declares_non_term:lst {:
	
		//jrTODO: BUG? this is strange!!! -> there must be a better way 
		//        to refer to these terminals.
		ComplexSymbol nonTerminal = (ComplexSymbol) stack.elementAt(stack.size()-2);		
		parserResult.symbols.add(new NonTerminalDeclaration(
							(List<NonTerminal>) lst,
							new Range(Position.fromComplexSymbolLeft(nonTerminal),
							Position.fromComplexSymbolRight((ComplexSymbol) stack.peek()))));
	:}
	
	|
	
	/* error recovery productions -- sync on semicolon */

	TERMINAL
	error 
	{:
	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	:}
	SEMI
	|
	non_terminal
	error 
	{:
	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	:}
	SEMI
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

declares_term ::=
	term_name_list : lst
	{: 
	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	  RESULT = lst;
	:}
	SEMI
	;
/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

declares_non_term ::=
	non_term_name_list : lst
	{: 
	  /* reset the accumulated multipart name */
	  multipart_name = new String();
	  RESULT = lst;
	:}
	SEMI
	;
/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

term_name_list ::= 
	term_name_list : lst COMMA new_term_id : item {:
		((List<Terminal>) lst).add((Terminal) item);
		RESULT = lst;
	:} | new_term_id:item {:
		List<Terminal> lst = new ArrayList<Terminal>();
		lst.add((Terminal) item);
		RESULT = lst;
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

non_term_name_list ::=
	non_term_name_list : lst COMMA new_non_term_id : item {:
		((List<NonTerminal>) lst).add((NonTerminal) item);
		RESULT = lst;
	:}
	|
	new_non_term_id : item {:
		List<NonTerminal> lst = new ArrayList<NonTerminal>();
		lst.add((NonTerminal) item);
		RESULT = lst;
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 


precedence_list ::= precedence_l | empty; 

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

precedence_l ::= precedence_l preced | preced;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

preced ::= 
	PRECEDENCE
	{:
		head_tokens.push((ComplexSymbol) stack.peek());
	:}
	preced_type
    terminal_list:lst SEMI
    {:
	  ComplexSymbol head = head_tokens.pop();
	  ast_add_precedence(head, lst);
    :}
	;

preced_type ::= 
	  LEFT     {: update_precedence(assoc.left);     :}
	| RIGHT    {: update_precedence(assoc.right);    :}
	| NONASSOC {: update_precedence(assoc.nonassoc); :}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

terminal_list ::= terminal_list:lst COMMA terminal_id:trm
	{:
		((List<Terminal>) lst).add(new Terminal(trm, 
	      			new Range(Position.fromLocation(trmxleft),
	      						Position.fromLocation(trmxright)))); // jrTODO: positions
		RESULT = lst;
	:}
	|
	terminal_id:trm
	{:
		List<Terminal> lst = new ArrayList<Terminal>();
		lst.add(new Terminal(trm, 
	      			new Range(Position.fromLocation(trmxleft),
	      						Position.fromLocation(trmxright)))); // jrTODO: positions
		RESULT = lst;
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

terminal_id ::= term_id:sym
	{:	
	  add_precedence(sym);
	  RESULT = sym;
	:};
	  
/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

term_id ::= symbol_id:sym
        {:
	  /* check that the symbol_id is a terminal */
	  if (symbols.get(sym) == null)
	    {
	      /* issue a message */
	      errMan.Error(ErrorSource.Parser, "Terminal \"" + sym + 
			   "\" has not been declared", Position.fromLocation(symxleft));
	    }
          RESULT = sym;
         :};

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

start_spec ::= 
	START{:
		head_tokens.push((ComplexSymbol) stack.peek());
	:} WITH nt_id:start_name 
	{: 
	  /* verify that the name has been declared as a non terminal */
	  non_terminal nt = (non_terminal)non_terms.get(start_name);
	  if (nt == null)
	    {
	    errMan.Error(ErrorSource.Parser, 
	    			"Start non terminal \"" + start_name + "\" has not been declared", 
	  		         Position.fromLocation(start_namexleft));
	    }
          else
	    {
	      /* remember the non-terminal for later */
	      start_nt = nt;

	      /* build a special start production */
	      new_rhs();
	      add_rhs_part(add_lab(new symbol_part(start_nt), "start_val"));
	      add_rhs_part(new symbol_part(terminal_shared.getEOF()));
	      if (!context.getXmlActions()) add_rhs_part(new action_part("RESULT = start_val;"));
	      context.start_production = 
		     new production(context, non_terminal_shared.getSTART_nt(), rhs_parts, rhs_pos);
	      new_rhs();
	      
	      //jrTODO: position, start symbol?, side effects?
	      parserResult.startWith = new StartWith(
	      							new NonTerminal (start_name, null),
	      							new Range(Position.fromComplexSymbolLeft(head_tokens.pop()),
	      							Position.fromComplexSymbolRight((ComplexSymbol) stack.peek())));
	      
	    }
	:}
	SEMI
	|
	empty
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

production_list ::= production_list production | production;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

production ::=
	nt_id : lhs_id
	{:
	  /* lookup the lhs nt */
	  lhs_nt = (non_terminal)non_terms.get(lhs_id);

          /* if it wasn't declared, emit a message */
	  if (lhs_nt == null)
	    {
	      if (errMan.getErrorCount() == 0)
	      errMan.Warning(ErrorSource.Parser, "LHS non terminal \"" + lhs_id + 
			       "\" has not been declared", 
	    		Position.fromLocation(lhs_idxleft));
	    }

	  /* reset the rhs accumulation */
	  new_rhs();
	:}
	COLON_COLON_EQUALS
/*	{: :}*/
	rhs_list : rhs
	SEMI : s
	{:
		parserResult.productions.add(
				new Production(
					new Name(
						(String) lhs_id,
						Range.fromLocations(lhs_idxleft, lhs_idxright)
					),
					(List<ProductionRight>) rhs,
					Range.fromLocations(lhs_idxleft, sxright)
				)
		);
	:}
	|
	error  : e {:
		errMan.Error(ErrorSource.Parser, "Production Syntax Error", Position.fromLocation(exleft));
	:}
	SEMI
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

rhs_list ::= rhs_list : lst BAR rhs : item {:
		if (item != null)
			((List<ProductionRight>) lst).add((ProductionRight) item);
		RESULT = lst;
	:} | rhs : item {:
		List<ProductionRight> lst = new ArrayList<ProductionRight>();
		if (item != null)
			lst.add((ProductionRight) item);
		RESULT = lst;
	:};

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

rhs ::= 
	prod_part_list PERCENT_PREC term_id:term_name 
	{:
	  symbol sym = null;
	  if (lhs_nt != null) 
	    {
	      /* Find the precedence symbol */
	      if (term_name == null) {
	      
	      // jrTODO: report proper error!
		System.err.println("No terminal for contextual precedence");
		sym = null;
	      } else {
	      symbol_part sp = null;
	      try{
		      sp = (symbol_part) symbols.get(term_name);
		  } catch (NullPointerException e) {
		  	// fix crash.
			errMan.Error(ErrorSource.Parser,
					"could not resolve symbol!",
					Position.fromLocation(term_namexleft));
		  }
	      if (sp != null)
			  sym = sp.the_symbol();
	      }
	      /* build the production */
	      production p;
	      if ((sym!=null) && (sym instanceof terminal)) {
		p = new production(context, lhs_nt, rhs_parts, rhs_pos,
				   ((terminal)sym).precedence_num(),
				   ((terminal)sym).precedence_side());
		((symbol_part)symbols.get(term_name)).the_symbol().note_use();
	      } else {
		System.err.println("Invalid terminal " + term_name + 
				   " for contextual precedence assignment");
		p = new production(context, lhs_nt, rhs_parts, rhs_pos);
	      }

	      /* if we have no start non-terminal declared and this is 
		 the first production, make its lhs nt the start_nt 
		 and build a special start production for it. */
              if (start_nt == null)
		{
		  start_nt = lhs_nt;

	          /* build a special start production */
	          new_rhs();
	          ast_new_rhs();
	          
	          add_rhs_part(add_lab(new symbol_part(start_nt),"start_val"));
	          add_rhs_part(new symbol_part(terminal_shared.getEOF()));
		  if (!context.getXmlActions()) add_rhs_part(new action_part("RESULT = start_val;"));
		  if ((sym!=null) && (sym instanceof terminal)) {
		    context.start_production = 
		      new production(context, non_terminal_shared.getSTART_nt(), rhs_parts, 
				     rhs_pos, ((terminal)sym).precedence_num(),
				     ((terminal)sym).precedence_side());
		  } else {
		    context.start_production = 
		      new production(context, non_terminal_shared.getSTART_nt(), rhs_parts, rhs_pos);
		  }
	          new_rhs();
	          ast_new_rhs();
		}
	    }
	  
	  // jrTODO
	  // RESULT = "blub!!!";

	  /* reset the rhs accumulation in any case */
	  new_rhs();
	  ast_new_rhs();
	:}
	|
	prod_part_list : ppl
	{:
	
		
	  if (lhs_nt != null) 
	    {
	      /* build the production */
	      production p = new production(context, lhs_nt, rhs_parts, rhs_pos);

		RESULT = new ProductionRight(ast_get_rhs_parts_copy(), 
						Range.fromLocations(pplxleft, pplxright));


	      /* if we have no start non-terminal declared and this is 
		 the first production, make its lhs nt the start_nt 
		 and build a special start production for it. */
        if (start_nt == null)
		{
		  start_nt = lhs_nt;

	          /* build a special start production */
	          new_rhs();
	          ast_new_rhs();
	          
	          add_rhs_part(add_lab(new symbol_part(start_nt),"start_val"));
	          add_rhs_part(new symbol_part(terminal_shared.getEOF()));
		  if (!context.getXmlActions()) add_rhs_part(new action_part("RESULT = start_val;"));
	          context.start_production = 
		     new production(context, non_terminal_shared.getSTART_nt(), rhs_parts, rhs_pos);

	          new_rhs();
	          ast_new_rhs();
		}
	    }
	  
	  
	  
	  /* reset the rhs accumulation in any case */
	  new_rhs();
	  ast_new_rhs();
	:} 
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

prod_part_list ::= prod_part_list prod_part | empty;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

prod_part ::=
	symbol_id:symid opt_label:labid
	{: 
	  /* try to look up the id */
	  production_part symb = (production_part)symbols.get(symid);

	  /* if that fails, symbol is undeclared */
	  if (symb == null) {
	      if (errMan.getErrorCount() == 0)
	        errMan.Error(ErrorSource.Parser, "Symbol \"" + symid + 
			       "\" has not been declared", Position.fromLocation(symidxleft));
	  }
	  else {
	      /* add a labeled production part */
	      add_rhs_part(add_lab(symb, labid));

		  ProductionRef ref = null;
		  Range range = new Range (Position.fromLocation(symidxleft), 
	      							Position.fromLocation(symidxright));
		  if (labid == null)
			  ref = new LabeledProductionRef(new Name(symid, range), labid, range);
		  else
			  ref = new ProductionRef(new Name(symid, range), range);
	      ast_add_rhs_part(ref);
	    }
	:}
	|
	CODE_STRING : code_str
	{:
	  /* add a new production part */
	  add_rhs_part(new action_part(code_str));
	  ast_add_rhs_part(new ActionCodeBlock(code_str, 
	  		Range.fromLocations(code_strxleft, code_strxright)
	  )); // jrTODO: positions
	:}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

opt_label ::=
	COLON label_id:labid
	{: RESULT = labid; :}
	|
	empty
	{: RESULT = null; :}
	;

/*. . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . */ 

multipart_id ::=
	multipart_id DOT robust_id:another_id
	{: multipart_name = multipart_name.concat("."+another_id); :}
	|multipart_id 
        {: multipart_names.push(multipart_name); multipart_name="";:}
        LT typearglist:types GT
         {: multipart_name =
         ((String)multipart_names.pop()).concat("<"+types+">"); :}
        |
	robust_id:an_id
	{: multipart_name = multipart_name.concat(an_id); :}
	;
/*. . . . . . . . . . . .TUM CHANGES. . . . . . . . . . . . . . . */


typearglist ::= 
            typearguement:arg
            {: RESULT = arg; :}
            | typearglist:list COMMA typearguement:arg
            {: RESULT = list + "," + arg; :}